Frontpage 2003 How To

How to Disable Certain FrontPage 2003 Commands by Using a GPO and a WSH Script

This step–by–step article discusses how to turn off specific FrontPage 2003 commands for all Windows XP and Windows 2000 domain clients by using a sample Windows Script Host (WSH) script and a Group Policy object (GPO).

• FrontPage 2003 Support

When you use the sample script that is in this article, and you add it to the Default Domain policy, the FrontPage 2003 client cannot perform any of the following actions:

• Formatting Options
  • Change themes
  • Insert Web components
• Advanced Functions
  • Customize menu and toolbar commands
  • Run macros
• Administrative Options
  • Change security settings
  • Change Web settings

Note – This article discusses making Group Policy changes at the domain level. You must always test domain–level Group Policy settings in a test environment before you make changes to your domain.

Disable Certain FrontPage 2003 Commands by Using a GPO and a WSH Script

To disable certain FrontPage 2003 commands by using a GPO and a WSH script, you must create the sample script. You must then copy the sample script to the logon scripts folder of the default domain policy, configure the sample script as the logon script, and then test the sample script from a client computer.

Create the Sample Script

To create the sample script:

1. Log on to your Windows domain controller as a user who is a member of the Domain Admins group.
2. Start Notepad, and then open a new document.
3. Copy the following code, and then paste the code to the new document:

   Option Explicit
   
   ' Continue if errors occur
   On Error Resume Next
   
   ' declare our variables
   Dim objFP
   Dim objCommandBar
   Dim objControl
   
   ' **************************************************
   ' This section checks to see if FrontPage is
   ' installed, and exits if it is not installed.
   ' **************************************************
   
   ' get a FrontPage Application object
   Set objFP = WScript.CreateObject("FrontPage.Application")
   
   ' exit if the object does not exist
   If Err.Number = -2147352567 Then WScript.Quit
   
   ' **************************************************
   ' This section disables inserting Web components.
   ' **************************************************
   
   ' get the 'Insert' command bar
   Set objCommandBar = objFP.Application.CommandBars("Insert")
   
   ' get the 'Web Component' control
   Set objControl = objCommandBar.Controls("&Web Component...")
   
   ' disable it
   objControl.Enabled = False
   
   ' **************************************************
   ' This section disables changing themes.
   ' **************************************************
   
   ' get the 'Format' command bar
   Set objCommandBar = objFP.Application.CommandBars("Format")
   
   ' get the 'Theme' control
   Set objControl = objCommandBar.Controls("T&heme...")
   
   ' disable it
   objControl.Enabled = False
   
   ' **************************************************
   ' This section disables modifying the toolbars, changing
   ' Web settings or permissions, and running macros.
   ' **************************************************
   
   ' get the 'Tools' command bar
   Set objCommandBar = objFP.Application.CommandBars("Tools")
   
   ' get the 'Customize' control
   Set objControl = objCommandBar.Controls("&Customize...")
   
   ' disable it
   objControl.Enabled = False
   
   ' get the 'Web Settings' control
   Set objControl = objCommandBar.Controls("&Web Settings...")
   
   ' disable it
   objControl.Enabled = False
   
   ' get the 'Server' control
   Set objControl = objCommandBar.Controls("Ser&ver")
   
   ' disable it
   objControl.Enabled = False
   
   ' get the 'Macro' control
   Set objControl = objCommandBar.Controls("&Macro")
   
   ' disable it
   objControl.Enabled = False
   
   ' **************************************************
   ' This section cleans up and exits.
   ' **************************************************
   
   Set objFP = Nothing
   WScript.Quit
   
   

4. To save the file, follow these steps:
   1. On the File menu, click Save.
   2. In the Save in box, click Desktop.
   3. In the Save as type box, click All Files, type Sample.vbs in the File name box, and then click Save.
5. Quit Notepad.

Copy the Sample Script to the Logon Scripts Folder of Your Default Domain Policy

To use the sample script with the Default Domain policy, determine the GUID for the GPO. Follow these steps:

1. Log on to your Windows domain controller as a user who is a member of the Domain Admins group (if you are not already logged on).
2. Start Active Directory Users and Computers.
3. Right-click DomainName, and then click Properties.
4. Click the Group Policy tab.
5. Click Default Domain Policy, and then click Properties.

6. Click the General tab.

   Make a note of the GUID of the Default Domain policy. The GUID of the Default Domain policy is listed next to Unique name in the Summary area.

7. Click Cancel, and then click Cancel.

8. To use the sample script with the GPO, copy Sample.vbs from your desktop to the following folder on the hard disk, where Domain is the fully qualified domain name (FQDN) of your domain (for example, MyDomain.local), and where GUID is the GUID number of the Default Domain policy.

   %SystemRoot%\SYSVOL\sysvol\Domain\Policies\GUID\User\Scripts\Logon

Configure the Sample Script As a Logon Script

To configure the sample script as a logon script, follow these steps:

1. Log on to your Windows domain controller as a user who is a member of the Domain Admins group (if you are not already logged on).
2. Start Active Directory Users and Computers.
3. Right-click DomainName, and then click Properties.
4. Click the Group Policy tab.
5. Click Default Domain Policy, and then click Edit.
6. In the left pane, under User Configuration, expand Windows Settings, and then click Scripts (Logon/Logoff).
7. In the right pane, double-click Logon.
8. Click Add.
9. In the Script Name box, click Browse, locate Sample.vbs, click Sample.vbs, click Open, and then click OK.
10. Click OK.
11. Quit Group Policy Object Editor, and then quit Active Directory Users and Computers.

Test the Sample Script from a Client Workstation

To test the sample script, follow these steps:

1. Log on to a Windows XP-based client computer or log on to a Windows 2000-based client computer.

   Note If you are already logged on to the computer, you must log off and then log back on again for the new Group Policy settings to apply to your computer.

2. Start FrontPage 2003. If a new page is not automatically opened, click New on the File menu.
3. Do the following:
   • On the Insert menu, verify that the Web Component command is unavailable.
   • On the Format menu, verify that the Theme command is unavailable.
   • On the Tools menu, verify that the Customize, the Macro, and the Server commands are unavailable.

Troubleshooting

To troubleshoot issues that may occur, follow these steps:

1. Retrace the steps in this article to make sure that the following conditions are true:
   • The syntax of the sample script is correct.
   • The sample script is copied to the correct Group Policy folder.
   • The sample script is added as a logon script, and it is not added as a logoff script, a startup script, or a shutdown script.
2. Log off the client computer, and then log back on to update the Group Policy settings.
3. Make sure that the client computer is a member of the domain where you added the logon script.

For additional information, click the following article number to view the article in the Microsoft Knowledge Base:

The information in this article applies to:

Microsoft Office FrontPage 2003, when used with:

• Microsoft Windows Server 2003, Standard Edition
• Microsoft Windows Server 2003, Enterprise Edition
• Microsoft Windows 2000 Server
• Microsoft Windows 2000 Advanced Server
• Microsoft Windows XP Professional
• Microsoft Windows XP Home Edition

Microsoft Knowledge Base Article - 825446